Blog do Bragil

Imports System.IO
Imports System.Drawing
Imports System.Data
Imports System.Web
Imports System.Web.UI
Imports System.Web.UI.WebControls
 
'''-----------------------------------------------------------------------------
''' Classe para geração de relatórios Excel. Utiliza o componente
''' System.Web.UI.WebControls.GridView para geração do arquivo .xls.
'''-----------------------------------------------------------------------------
Public Class ExcelReport
 
    ''' Nome do arquivo Excel
    Private _file As String
 
    ''' Objeto GridView
    Private gv As GridView
 
    ''' Construtor, recebe o nome do arquivo .xls como parâmetro
    ''' String contendo o nome do arquivo .xls a ser gerado.
    Public Sub New(ByVal file As String)
        Me._file = file
 
        ' Cria o GridView
        gv = New GridView()
 
        ' Formatação do GridView para que a planilha fique "zebrada"
        gv.HeaderStyle.ForeColor = Color.Black
        gv.AlternatingRowStyle.BackColor = Color.Yellow
        gv.RowStyle.BackColor = Color.White
 
    End Sub
 
    ''' Gera um arquivo Excel a partir de um DataTable.
    ''' Instância do objeto DataTable
    Public Sub DataTableToExcel(ByRef dt As DataTable)
 
        If dt.Rows.Count < 65536 Then
            Dim response As HttpResponse = HttpContext.Current.Response
            response.Clear()
            response.AddHeader("Content-Disposition", "attachment; filename=" + Me._file)
            response.ContentType = "application/vnd.ms-excel"
            Dim stringWrite As New StringWriter
            Dim htmlWrite As New HtmlTextWriter(stringWrite)
            gv.DataSource = dt
            gv.DataBind()
            gv.RenderControl(htmlWrite)
            response.Write(stringWrite.ToString)
            response.End()
        Else
            ' se tiver mais que 65536 linhas, dispara a exception
            Throw New Exception("Consulta deve conter menos que 65536 linhas")
        End If
    End Sub
End Class